เรียนรู้ XML กับ Visual Basic 6.0 ภาค 2

<?xml version="1.0" encoding="ISO-8859-1"?>
<CATALOG>  <!-- Comment: นี่คือ Root หรือ ราก -->
	<CD>  <!-- Comment: Child -->
		<!-- Comment: Sub Child -->
		<TITLE>Empire Burlesque</TITLE>
		<ARTIST>Bob Dylan</ARTIST>
		<COUNTRY>USA</COUNTRY>
		<COMPANY>Columbia</COMPANY>
		<PRICE>10.90</PRICE>
		<YEAR>1985</YEAR>
	</CD>
	<CD>
		<TITLE>Hide your heart</TITLE>
		<ARTIST>Bonnie Tyler</ARTIST>
		<COUNTRY>UK</COUNTRY>
		<COMPANY>CBS Records</COMPANY>
		<PRICE>9.90</PRICE>
		<YEAR>1988</YEAR>
	</CD>
</CATALOG>

จากบทความนี้ผมจะนำเสนอเรื่องราวของ Stream Object ครับ ซึ่ง Object ตัวนี้มันได้ฝังมากับ ActiveX Data Object 2.5 เป็นต้นมา อนึ่งในตำราภาคภาษาอังกฤษมันกล่าวถึงเรื่องของ Stream Binary Data รวมถึง Document และ Folder เอาไว้ ดังนั้นผมขออธิบายความหมายตามแบบฉบับที่ผมเข้าใจให้พี่น้องได้รับฟังกันน่ะครับ ... Stream Object มันเป็น Object ที่ใช้ในการเข้าถึงข้อมูลในลักษณะโครงสร้างแบบต้นไม้ (Tree) แต่เป็นต้นไม้กลับหัวน่ะครับ คือ เอาราก หรือ Root ไปไว้ด้านบนสุด จากนั้นก็แตกกระจายเป็นกิ่ง ก้าน สาขา ลงมา โดยแต่ละจุดที่มันเกิดการแตกกระจาย เราเรียกว่า โหนด (Node) หรือ Child/Sub Child ตามลักษณะของ XML ซึ่ง Stream Object มันสามารถทำงานร่วมกันกับ RecordSet Object ได้ด้วย ... ดังตัวอย่างข้างล่างนี้แหละครับ
อ่านรายละเอียดเพิ่มเติมของ Stream Object ... ที่นี่

เห็นมั้ยครับ ... เข้าทาง XML มันเลย ลองดูรูปแบบของ XML ทางด้านซ้ายมือ เราจะพบว่าตรงตำแหน่งของ <CATALOG> หรือ Root มันก็คือ Recordset (หรือตารางข้อมูลดีๆนี่แหละ) ส่วน <CD> หรือ Child มันก็คือ Record ในแต่ละรายการ ส่วนจะชี้ว่ามี Identifier หรือ Primary Key ใด เราก็สามารถเพิ่มเติมได้จาก Sub Child หรือ กำหนดเป็น Attribute ให้กับ Child โดยตรงเลยก็ได้ เช่น <CD ID="1"> เหอๆๆๆๆ ... ง่ายจัง

Option Explicit

' ประกาศตัวแปรสำหรับ ADO Stream Object
Dim strData As New ADODB.Stream

' โปรแกรย่อยที่ใช้ในการแปลงข้อมูล และั ทำการแสดงผล
Private Sub cmdSearch_Click()
Dim Criteria As String
Criteria = Trim(txtSearch.Text)
    Set RS = New Recordset
    
    ' ตัวอย่างเลือกจากการค้นหาข้อมูล
    If Criteria <> "" Or Len(Criteria) <> 0 Then
        ' ตัวอย่างตารางเดียว
        'RS.Open "SELECT * FROM tblCustomer WHERE " & _
                            " [FirstName] " & " Like '%" & Criteria & "%'" & " OR " & _
                            " [LastName] " & " Like '%" & Criteria & "%'" & _
                            " ORDER BY CustomerID ", _
                            ConnMyDB, adOpenForwardOnly, adLockReadOnly, adCmdText
        
        ' QUERY
        RS.Open " SELECT tblCustomer.*, tblTitle.TitleName, tblProvince.ProvinceName " & _
                            " FROM (tblCustomer INNER JOIN tblProvince ON tblCustomer.ProvinceID = tblProvince.ProvinceID) " & _
                            " INNER JOIN tblTitle ON tblCustomer.TitleID = tblTitle.TitleID " & _
                            " WHERE " & _
                            " [CustomerID] " & " Like '%" & Criteria & "%'" & " OR " & _
                            " [FirstName] " & " Like '%" & Criteria & "%'" & " OR " & _
                            " [LastName] " & " Like '%" & Criteria & "%'" & " OR " & _
                            " [TitleName] " & " Like '%" & Criteria & "%'" & _
                            " ORDER BY CustomerID ", _
                            ConnMyDB, adOpenForwardOnly, adLockReadOnly, adCmdText

    Else
        ' ตัวอย่างตารางเดียว
        'RS.Open " SELECT * FROM tblCustomer " & _
                            " ORDER BY CustomerID ", _
                            ConnMyDB, adOpenForwardOnly, adLockReadOnly, adCmdText
        RS.Open " SELECT tblCustomer.*, tblTitle.TitleName, tblProvince.ProvinceName " & _
                            " FROM (tblCustomer INNER JOIN tblProvince ON tblCustomer.ProvinceID = tblProvince.ProvinceID) " & _
                            " INNER JOIN tblTitle ON tblCustomer.TitleID = tblTitle.TitleID " & _
                            " ORDER BY CustomerID ", _
                            ConnMyDB, adOpenForwardOnly, adLockReadOnly, adCmdText
    End If
    
    ' กำหนดให้ RecordSet เพื่อรับค่ารูปแบบของ XML อันนี้ต้อง Define ก่อนใช้ Method - SaveToFile
    RS.Save strData, adPersistXML
    
    ' บันทึกผลที่ได้ไปสู่เอกสาร XML ตามที่ระบุไว้
    ' adSaveCreateOverWrite เพื่อสร้างไฟล์ใหม่หากไม่มีไฟล์นั้นๆ และเขียนทับลงไปหากมีไฟล์เดิมอยู่แล้ว
    strData.SaveToFile App.Path & "\MyDB.xml", adSaveCreateOverWrite
    
    ' นำไฟล์ XML มาแสดงผลบน Web Browser
    webXML.Navigate App.Path & "\MyDB.xml"
    
    ' นำไฟล์ XML มาแสดงผลในตารางกริด
    Set DS = New Recordset
    DS.Open App.Path & "\MyDB.xml", "Provider=MSPersist;", _
            adOpenForwardOnly, adLockReadOnly, adCmdText
    ' ผูก Control เข้ากับแหล่งข้อมูล
    Set fg.DataSource = DS
    
    ' ปิดการใช้งาน
    DS.Close: Set DS = Nothing
    RS.Close: Set RS = Nothing
    strData.Close: Set strData = Nothing

End Sub

Private Sub Form_Load()
    Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    Me.Height = Me.ScaleHeight
    Me.Width = Me.ScaleWidth
    
    txtSearch.Text = ""
    ' ให้แสดงหน้า HTML ว่างเปล่า
    webXML.Navigate App.Path & "\Blank.html"
    
    ' เชื่อมต่อไฟล์ฐานข้อมูล MS Access ... เข้าสู่ Module หากินอีกแล้ว 55555
    Call OpenDataBase
End Sub

Private Sub Timer1_Timer()
    ' แสดงเวลาแบบ Real Time
    staProgram.Panels(3).Text = Format(Hour(Time), "00") & ":" & _
                                                              Format(Minute(Time), "00") & ":" & _
                                                              Format(Second(Time), "00") & "  " & _
                                                              FormatDateTime(Now(), vbShortDate)
End Sub

Private Sub txtSearch_KeyPress(KeyAscii As Integer)
    If KeyAscii = vbKeyReturn Then
        ' ปิดเสียงลำโพง ... หนวกหู
        KeyAscii = 0
        Call cmdSearch_Click
    End If
End Sub