เรียนรู้ Visual Basic 6.0 กับ ฐานข้อมูล MS Access ภาค 11/2

' วิธีการคำนวณหาค่า Primary Key หรือ PK
' การใช้งานจริง ... แนะนำให้แก้ไขเป็น Public Function ด้วยน่ะครับ
' ส่งแค่ชื่อตารางข้อมูลเข้ามา เพราะผมตั้งชื่อฟิลด์ PK (Primary Key) เหมือนกันอยู่ทุกๆตารางไงล่ะ ... เอิ๊กๆๆๆๆ
' อ้อ ... แล้วส่งค่ากลับแบบ Long Integer ด้วยน่ะ ... มือใหม่ก็คงจะงงเป็นแถวเลย 55555 (มันแปลว่าไรฟ่ะ)
Sub SetupNewData()
Dim Rec As Long
Set DS = New Recordset
    ' นำข้อมูลจากตารางมาหาจำนวนสูงสุด
    ' ต้องระมัดระวังในการจัดเรียงข้อมูลด้วยน่ะครับผม
    ' มีวิธีอื่นๆนอกจากนี้เยอะแยะไป ... ลองไปฝึกหัดคิดด้วยตัวเองบ้างเน้อ
    Statement = "SELECT * FROM tblProduct ORDER BY PK "
    DS.Open Statement, ConnMyDB, adOpenForwardOnly, adLockReadOnly, adCmdText
    Rec = 0
    ' จุดเริ่มต้นของ Begin of File (BOF) กับ End Of File (EOF) มันเท่ากัน ก็แสดงว่าไม่มีข้อมูล
    If DS.BOF Or DS.EOF Then
        Rec = 0
    Else
        ' หากใช้วิธีการนับ ค่าสุดท้ายที่ได้จะไม่ตรง ... เพราะบางครั้งเราอาจทำการลบรายการบางส่วนออกไป
        DS.MoveLast
        Rec = DS("PK")
    End If
    Rec = Rec + 1   ' เพิ่มจำนวน PK
    PK = Rec
    DS.Close: Set DS = Nothing
End Sub

เทคนิคของการตรวจสอบรหัสสินค้า ... หรือเหล่าบรรดารหัสลูกค้า/รหัสผู้จำหน่ายสินค้า
Sub RecordToScreen()
Set DS = New Recordset
    ' นำข้อมูลจากตารางมาแสดงผล
    ' พี่น้องครับ ... ไม่ต้องมาจดจำการ Join กันของตารางหรอกครับ
    ' ผมแนะนำให้ใช้งาน Query ที่อยู่ใน MS Access เป็นตัวทดสอบก่อน
    ' เมื่อได้ผลลัพธ์ดั่งใจที่ต้องการแล้ว ก็ค่อยทำการตัดแปะมาใส่ ... ง่ายกว่ากันเยอะเลย
    ' บางอย่างก็ควรทำด้วยความเข้าใจ ... แบบไม่ต้องมานั่งท่องจำให้ปวดกะโหลกหรอกครับ
    ' อีกอย่าง ... เขามีเครื่องมือมาให้ใช้แล้ว ก็ควรจะใช้มันให้คุ้มค่าด้วยล่ะกัน ... เหอๆๆๆๆๆ
    Statement = "SELECT tblProduct.*, " & _
                            " tblProductGroup.ProductGroupName, " & _
                            " tblBrandName.BrandName, " & _
                            " tblUnit.UnitName " & _
                            " FROM tblUnit INNER JOIN (tblBrandName INNER JOIN " & _
                            " (tblProductGroup INNER JOIN tblProduct ON " & _
                            " tblProductGroup.PK = tblProduct.ProductGroupFK) ON " & _
                            " tblBrandName.PK = tblProduct.BrandNameFK) ON " & _
                            " tblUnit.PK = tblProduct.UnitFK " & _
                            " WHERE [tblProduct.PK] = " & PK & _
                            " ORDER BY [tblProduct.PK] "

        DS.Open Statement, ConnMyDB, adOpenForwardOnly, , adCmdText
        ' นำข้อมูลมาแสดงผลบนหน้าจอ
        txtProductCode.Text = "" & DS("ProductCode")
        ' ============================================================
        ' เก็บค่า ProductCode เดิมไว้ก่อน เพื่อทดสอบว่ามีค่าซ้ำกันหรือไม่ ก่อนที่จะทำการบันทึกผล
        ' ดูจากการเกิดเหตุการณ์ cmdSave_Click น่ะครับ ... พี่น้อง
        ' นั่นคือการนำคุณสมบัติ Tag ของ TextBox มาใช้งานให้เกิดประโยชน์ ... โดยเราเอาค่าเดิมมาซ่อนเอาไว้ก่อน
        ' เทคนิคการใช้งานแบบนี้ ... ขอบอกครับขอบอก นำไปใช้งานได้สารพัดอย่างแหละ (แต่อย่าใช้มันไปซื้อโอเลี้ยงให้น่ะ ... 55555)
        txtProductCode.Tag = txtProductCode.Text
        ' ...
        ' ...
        ' ...


End Sub

เทคนิคของการตรวจสอบรหัสสินค้า ... ก่อนทำการบันทึกผลเก็บเข้าสู่ตารางข้อมูล
Private Sub cmdSave_Click()
    ' ProductCode
    If Trim(txtProductCode.Text) = "" Or Len(Trim(txtProductCode.Text)) = 0 Then
        MsgBox "กรุณาป้อนรหัสสินค้าให้เรียบร้อยก่อนด้วย.", vbOKOnly + vbExclamation, "รายงานสถานะ"
        txtProductCode.SetFocus
        Exit Sub
    ElseIf Trim(txtDescription.Text) = "" Or Len(Trim(txtDescription.Text)) = 0 Then
        MsgBox "กรุณาป้อนชื่อสินค้าให้เรียบร้อยก่อนด้วย.", vbOKOnly + vbExclamation, "รายงานสถานะ"
        txtDescription.SetFocus
        Exit Sub
    End If
    '
' หากมีการเปลี่ยนแปลงค่าข้อมูลของ ProductCode
' txtProductCode.Tag เราพิจารณาได้จาก 2 เหตุการณ์ คือ
' 1. เพิ่มข้อมูลใหม่ กรณีนี้ค่าใน Tag เดิมก็จะเป็นค่าว่างอยู่แล้ว
' 2. แก้ไขข้อมูล กรณีนี้ให้ไปดูจากโปรแกรมย่อย RecordToScreen จะเห็นได้ว่ามีการเก็บค่า
' ลงใน Tag ไว้ก่อนล่วงหน้าแล้ว ... อย่าลืมครับ Visual Basic มันมีสาระสำคัญอยู่ที่ Events/Driven
If txtProductCode.Text <> txtProductCode.Tag Then
    If CheckExistCode > 0 Then
        MsgBox "มีรหัสสินค้า: " & Trim(txtProductCode.Text) & " เรียบร้อยแล้ว กรุณาแก้ไขใหม่ด้วย.", _
                        vbOKOnly + vbExclamation, "รายงานสถานะ"
        Exit Sub
    End If
End If

' ในเหตุการณ์นี้เราจะทำการดัก Error ที่เกิดขึ้นก่อนทำการบันทึกข้อมูลครับ ... พี่น้อง
' เมื่อไม่มี Error หรือ ความผิดพลาดแล้ว ก็ค่อยไปโปรแกรมย่อย SaveData
Call SaveData

End Sub

' ฟังค์ชั่นที่ใช้ในการตรวจสอบรหัสสินค้าว่าซ้ำกันหรือไม่
Function CheckExistCode() As Byte
    Set DS = New Recordset
    SQLStmt = "SELECT * FROM tblProduct  WHERE [ProductCode] = " & "'" & Trim(txtProductCode.Text) & "'" & _
                            " ORDER BY [PK]"
    
    DS.CursorLocation = adUseClient
    DS.Open SQLStmt, ConnMyDB, adOpenForwardOnly, adLockReadOnly, adCmdText
    
    ' คืนค่ากลับเป็นจริงหากมีค่าซ้ำกัน แสดงว่า DS.RecordCount ต้องมีค่ามากกว่า 0
    CheckExistCode = DS.RecordCount
    DS.Close:    Set DS = Nothing
End Function