การกำหนด Path ของไฟล์ฐานข้อมูลด้วยคำสั่ง GetSetting/SaveSetting

Option Explicit

' =============================================================
' เทคนิคการ Optimized (พยายามลดต้นทุนที่ใช้ ซึ่งมันก็จะเกิดกำไรเองนั่นแหละ)
' =============================================================
' การประกาศ และ กำหนดการเชื่อมต่อฐานข้อมูล ทำเพียงครั้งเดียวก็พอแล้วครับ
Global ConnDB As New ADODB.Connection

' หมายเหตุ: ... พี่น้องครับ พยายามลดตัวแปรในการเชื่อมต่อตารางข้อมูลไว้บ้างก็ดีน่ะครับ
' ไม่ใช่เล่นต้องมาประกาศเอาใหม่หมดทุกๆตาราง ... แบบตามตำรากันเป๊ะๆจังเลยน่ะ
' ตั้งแต่ผมเขียนโปรแกรมด้วย VB6 มา ผมใช้ตัวแปร RecordSet ไม่เกิน 3 ตัวสักงานเลย
' Global RS As New ADODB.Recordset   ' เราให้เป็นตัวหลัก
' Global DS As New ADODB.Recordset   ' กำหนดให้เป็นตัวรอง
' หรือประกาศแบบขำๆ ... Dim RS กะ Dim GRAMMY เอาเองน่ะครับ เอิ๊กๆๆๆๆ

' ส่วนนี้ก็สำหรับการทำ Query Statement ก็ประกาศไม่กี่ตัว ก็พอเหลือใช้แล้ว
' Global Statement As String
' Global SQLStmt As String
' =============================================================

' มาอีกแล้ว ... โมดูลหากิน 55555+
' ==================== การเชื่อมต่อฐานข้อมูล ==========================
Public Sub OpenDataBase()
On Error GoTo Err_Handler
Dim DB_File As String

    ' อ่านตำแหน่งของไฟล์ฐานข้อมูลเข้ามาก่อนด้วยโปรแกรมย่อย (ฟังค์ชั่น) ReadLocation
    ' ReadLocation จะส่งค่าตำแหน่งของไฟล์ข้อมูลกลับมาหา DB_File
    DB_File = ReadLocation()
    
    ' เปิดการเชื่อมต่อฐานข้อมูล
    Set ConnDB = New ADODB.Connection
    ConnDB.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=" & DB_File & ";" & _
        "Persist Security Info=False;"
    ConnDB.Open

ExitProc:
    Exit Sub
    
Err_Handler:
    ' หาไฟล์ไม่เจอ ...
    If Err.Number = -2147467259 Then
        ' แปลความหมายเป็นภาษามนุษย์ให้กับผู้ใช้งานได้เข้าใจง่ายๆ
        ' อันที่จริงแล้ว กรณีนี้เราควรต้องเพิ่ม ADOX เข้ามาเพื่อช่วยในการสร้างไฟล์+ตารางข้อมูลเข้ามาใหม่
        ' โอกาสหน้าจะมาว่ากันต่อเรื่อง ADOX ครับ ... เพราะเรื่องมันยาว
        MsgBox "Open Database Error : " & Err.Number & vbCrLf & _
                        "ไม่พบไฟล์ข้อมูล : " & Mid$(Err.Description, 21, Len(Err.Description)) & vbCrLf & _
                        "กรุณานำไฟล์ข้อมูลไปเก็บไว้ในตำแหน่งที่คุณระบุด้วย.", vbCritical + vbOKOnly, "รายงานสถานะ"
        'Resume ExitProc
        End
    Else
        MsgBox "Open Database Error : " & vbCrLf & Err.Number & " " & Err.Description
        Resume ExitProc
    End If
End Sub

Public Sub CloseDataBase()
    ' ตรวจสอบว่ามีการเชื่อมโยง - Connect ข้อมูลหรือไม่
    If ConnDB.State = adStateOpen Then
        ConnDB.Close
        Set ConnDB = Nothing
    End If
End Sub

' ส่วนของการอ่านค่าจาก Registry ... ส่งค่ากลับเป็นแบบ String
Public Function ReadLocation() As String
    ' ตำแหน่งของ Registry สำหรับการใช้งาน GetSetting/SaveSetting
    ' Start --> Run --> พิมพ์ regedit
    
    ' หาก Return ค่ากลับมาจาก GetSetting เป็นค่าว่าง ... ก็ให้ใส่ Path ปัจจุบัน และ ชื่อไฟล์ MS Access เข้ามาเลย
    ' ส่วนแรก คือ AppName ... ตั้งชื่อเป็น MyAppName
    ' ส่วนที่ 2 คือ Section ... ตั้งชื่อเป็น MySection
    ' และส่วนสุดท้าย คือ Key ... ตั้งชื่อเป็น MyKey - ส่วนนี้คือส่วนที่ใช้จัดเก็บตำแหน่งของไฟล์ข้อมูล (Value)
    If GetSetting("MyAppName", "MySection", "MyKey") = "" Then
        ' ส่วนสุดท้ายจะเป็น Value หรือ ตำแหน่งของไฟล์ข้อมูลนั่นเอง
        Call SaveSetting("MyAppName", "MySection", "MyKey", App.Path & "\Employee.mdb")
    End If
        
    ' ส่งค่ากลับไปแบบ String
    ReadLocation = GetSetting("MyAppName", "MySection", "MyKey")

End Function

' การบันทึกค่าลง Registry
' ต้องรับค่าชื่อ TextBox Control เข้ามาด้วย (ในที่นี้คือ txtSelectMDB)
Public Sub WriteLocation(Ctrl As TextBox)
    ' บันทึกค่าจาก TextBox เข้าสู่ Registry ... เพื่อกำหนด Path ให้กับไฟล์ฐานข้อมูล
    Call SaveSetting("MyAppName", "MySection", "MyKey", Ctrl)
End Sub