Visual Basic 6.0 กับการทำรายงานด้วย Active Report ตอนที่ 1

Option Explicit
' ประกาศตัวแปรแบบ Object เพื่อรับงานไปพิมพ์
Dim rptPrint As Object
' ตัวแปรที่ใช้ในระบุการค้นหา หรือ กำหนดช่วงการพิมพ์หรือไม่
Dim blnSearch  As Boolean

Private Sub Form_Load()
On Error GoTo ErrorHandler
    Me.Move (Screen.Width - Me.Width) \ 2, (Screen.Height - Me.Height) \ 2
    ' เชื่อมต่อฐานข้อมูล
    Call OpenDataBase
    
    With ARViewEmployeeList
        .Zoom = 100   ' ค่า % การแสดงผล
        ' และอื่นๆอีก ... เอาไว้ตอนหน้าล่ะกัน
    End With
    
    ' ตั้งค่าเป็นเท็จเพื่อบ่งบอกว่าไม่ใช่การค้นหาข้อมูล
    blnSearch = False
    ' อันที่จริงก่อนทำการ Preview ผมจะทำเป็นฟังค์ชั่นแทนเอา เช่น PreviewReport(False)
    ' เวลาประกาศในฟังค์ชั่น ก็จะประกาศแบบนี้ ... Function PreviewReport(blnSearch As Boolean)
    ' เพราะสั่งแบบนี้มันง่าย และ สะดวกกว่าเยอะครับ
ExitProc:
    Exit Sub
    
ErrorHandler:
    MsgBox "Error : " & Err.Number & vbCrLf & Err.Description, vbOKOnly + vbExclamation, "รายงานความผิดพลาด"
    Resume ExitProc
End Sub

' เกิดเหตุการณ์กดปุ่ม Preview หรือ cmdPreview_Click

Private Sub cmdPreview_Click()
    Set RS = New ADODB.Recordset
    ' ให้แสดงผลทั้งหมดน่ะมันนาน ... จริงๆแล้วต้องเลือกเฉพาะรายการที่ต้องการมากกว่า
    ' การค้นหา หรือ กำหนดช่วงข้อมูล
    ' อันนี้พี่น้องต้องลองไปใส่ไอเดียของตัวเองเข้าไปด้วยล่ะกันครับ
    If blnSearch Then
        Statement = "SELECT tblEmployee.EmployeePK, tblEmployee.EmployeeID, tblEmployee.EmployeeName, " & _
                                " tblEmployee.DateStart, tblPosition.PositionName, tblDepartment.DepartmentName " & _
                                " FROM (tblPosition INNER JOIN tblEmployee ON tblPosition.PositionPK = " & _
                                " tblEmployee.PositionFK) INNER JOIN " & _
                                " tblDepartment ON tblEmployee.DepartmentFK = tblDepartment.DepartmentPK " '& _
                                " [EmployeeID] " & " Like '%" & Trim(txtSearch.Text) & "%'" & " OR " & _
                                " [EmployeeName] " & " Like '%" & Trim(txtSearch.Text) & "%'" & " OR " & _
                                " [PositionName] " & " Like '%" & Trim(txtSearch.Text) & "%'" & " OR " & _
                                " [DepartmentName] " & " Like '%" & Trim(txtSearch.Text) & "%'" & _
                                " ORDER BY EmployeeID "
                                ' หรือ BETWEEN ...
    ' ให้แสดงผลออกมาทั้งหมด
    Else
        Statement = "SELECT tblEmployee.EmployeePK, tblEmployee.EmployeeID, tblEmployee.EmployeeName, " & _
                                " tblEmployee.DateStart, tblPosition.PositionName, tblDepartment.DepartmentName " & _
                                " FROM (tblPosition INNER JOIN tblEmployee ON tblPosition.PositionPK = " & _
                                " tblEmployee.PositionFK) INNER JOIN " & _
                                " tblDepartment ON tblEmployee.DepartmentFK = tblDepartment.DepartmentPK " & _
                                " ORDER BY EmployeeID "
    End If
    '
    RS.Open Statement, ConnDB, adOpenForwardOnly, adLockReadOnly, adCmdText
    
    ' =====================================================
    ' ส่วนสำคัญในการทำรายงานด้วย Active Report
    ' ตั้งค่า หรือ การผูกรายงานเข้ากับ Object
    Set rptPrint = New arEmployeeList   ' มาจากชื่อไฟล์รายงาน (Designer)
    
    ' ARViewEmployeeList ตัวนี้คือ ARViewer Control ที่วางไว้อยู่บนฟอร์ม frmPrintEmployee
    Set Me.ARViewEmployeeList.object = rptPrint
    
    ' ผูกฐานข้อมูล (Bound Control) แบบ Run Time เข้ากับ Object
    ' dcRptData ตัวนี้มันไปอยู่ที่แบบฟอร์มรายงานของ ActiveReport (Designer) น่ะครับ
    Set rptPrint.dcRptData.Recordset = RS
    ' RecordSet ตัวนี้นี่แหละที่ถูกส่งออกไปยัง Designer โดย dcRptData จะเป็นตัวรับค่า
    ' =====================================================
End Sub

' เมื่อผูกค่าต่างๆเข้าหากันแล้ว ... ต่อไปก็จะกระโดดไปทำงานยัง Designer ที่เราออกแบบเอาไว้
' เริ่มต้นการตั้งค่าต่างๆที่นี่ ... เหมือนกับ Form_Load ใน MS Visual Basic ครับ
Private Sub ActiveReport_Initialize()
    ' การควบคุมการทำงานแบบ Run Time จะมีประสิทธิภาพที่ดีกว่า Design Time
    ' ขนาดของกระดาษ
    PageSettings.PaperSize = 9 ' A4
    ' ตั้งค่าในแนวตั้ง
    PageSettings.Orientation = ddOPortrait
    ' หรือแนวนอน
    ' PageSettings.Orientation = ddOLandscape
    ' หน่วย Twip น่ะครับ นั่นคือ 1440 Twip = 1 นิ้ว หรือ 2.54 Cm.
    ' อยากได้หน่วยวัดแบบไหนก็ทำบัญญัติไตรยางค์หาค่าเอาเองครับ
    PageSettings.LeftMargin = 300
    PageSettings.RightMargin = 300
    PageSettings.BottomMargin = 300
    PageSettings.TopMargin = 300
    ' เคลียร์ค่าก่อนทำการแสดงผล
    txtItem.Text = ""
    txtEmployeeID.Text = ""
    txtName.Text = ""
    txtPosition.Text = ""
    txtDepartment.Text = ""
    txtDateStart.Text = ""
    txtDayWork.Text = ""
    lblContinued.Caption = ""
End Sub

' รายละเอียดต่างๆก็จะนำมาแสดงใน Detail อยู่แล้ว
Private Sub Detail_Format()
' อยากให้พี่น้องลองทดสอบเอาเองครับ ว่าหากเราไม่ใช้ตัวแปร i เป็น Static แล้วผลที่ได้มันจะเป็นยังไง
'Dim i As Long
' เก็บค่าของตัวแปร i เอาไว้ตลอด ... นานๆครั้งที่ได้ใช้ตัวแปรแบบนี้
Static i As Long
    i = i + 1
    txtItem.Text = i & "."
    ' dcRptData ก็คือ ADO Control ที่เรานำมาวางไว้บนรายงานนั่นแหละ
    ' เพียงแต่เราผูกฐานข้อมูลเข้า (Bound Control) ตอนสั่ง Run Time โดยวิธีที่สุดแสนจะง่ายดาย
    ' rptPrint.dcRptData.Recordset = RS ในฟอร์มพิมพ์งาน (frmPrintEmployee)
    ' จากนั้นแต่ละฟิลด์ (จาก Query ที่อยู่ในฟอร์ม frmPrintEmployee) เราก็นำมาผูกเข้ากับ TextBox Control
    ' ดังนั้น ... อย่าลืมต้องสร้างความสัมพันธ์ให้มันตรง หรือ สอดคล้องกันด้วยน่ะขอรับ
    txtEmployeeID.Text = "" & Trim(dcRptData.Recordset("EmployeeID"))
    txtName.Text = "" & Trim(dcRptData.Recordset("EmployeeName"))
    txtPosition.Text = "" & Trim(dcRptData.Recordset("PositionName"))
    txtDepartment.Text = "" & Trim(dcRptData.Recordset("DepartmentName"))
    txtDateStart.Text = FormatDateTime(dcRptData.Recordset("DateStart"), vbShortDate)
    ' เรียกใช้งาน Public Function CalcDate(วันที่เริ่มงาน, วันที่ปัจจุบัน) ... ส่งค่ากลับมาเป็น String
    txtDayWork.Text = "(อายุงาน: " & CalcDate(txtDateStart.Text, Now) & ")"
    ' กลไกของมันต่อไป คือ การวนรอบอีก จนกว่าข้อมูลใน dcRptData จะหมดลงนั่นเอง
    
    ' ======================================================================
    ' มองให้ชัดๆ นั่นก็คือ คุณสามารถทำการคำนวณ หรือ ตั้งค่าสูตรต่างๆได้ด้วยตัวคุณเอง
    ' โดยค่าต่างๆที่เราใช้คำนวณ มันจะถูกนำมาแสดงผลลง TextBox หรือ Label Control ได้อย่างง่ายมาก
    ' และที่สำคัญ ... มันทำงานแบบ Real Time ครับพี่น้อง
    ' มาถึงตรงนี้ ... คุณคิดว่าถึงเวลาที่จะสลัดรักเจ้า Crystal Report ได้แล้วหรือยัง ... 55555
    ' ======================================================================
End Sub

' ส่งออกเป็นไฟล์ MS Excel ก็สุดแสนจะง่ายดาย (ซ่ะไม่มีล่ะ)
Private Sub cmdExportExcel_Click()
' ====================================================================
' ก่อนใช้งานอย่าลืมไปเลือก Project --> References ... --> ActiveReports Excel Export Filter
' ====================================================================
    Dim oEXL As ActiveReportsExcelExport.ARExportExcel
    Set oEXL = New ActiveReportsExcelExport.ARExportExcel
    ' ส่งออกไปที่ไฟล์ MS Excel
    ' หากต้องการให้ผู้ใช้งาน ตั้งชื่อไฟล์เอาเอง ก็นำ Common Dialog Control มาใช้งาน
    ' ในเว็บไซต์แห่งนี้มีให้พี่น้องอยู่แล้ว ... โปรดเลือกเอามาใช้งานเองเถิด
    oEXL.FileName = App.Path & "\EXCELTest.xls"
    oEXL.Export rptPrint.Pages
End Sub