แจกฟรีโค้ดโปรแกรม VB6 ป้องกันการคัดลอกข้อมูลจากคอมพิวเตอร์ไปยัง Flash Drive

Option Explicit

'---------------------------------------------------------------------------------------------------------
Private Sub Form_Load()
'---------------------------------------------------------------------------------------------------------
    Me.Move (Screen.Width - Me.Width) \ 2, (Screen.Height - Me.Height) \ 2
    
    Dim strKey As String

    ' กำหนดค่าที่ใช้ในการทำ Registry Edit เพื่อทดสอบว่ามีการเปิด หรือ ปิดการใช้งาน Registry Tool หรือไม่
    strKey = "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\" & _
                "Policies\System\DisableRegistryTools"
    ' ผมใช้การเขียนเป็นฟังค์ชั่นเพื่อลดจำนวนโค้ดลงไป หากเรามีการปรับค่าใน Registry จำนวนมากๆ
    
    ' ส่งค่า Key ที่เราต้องการทดสอบไป โดยพิจารณาจากค่า DisableRegistryTools
    ' หากคืนค่ากลับมาเป็น 0 แสดงว่าสามารถใช้งาน Registry Tools ได้
    ' หากคืนค่ากลับมาเป็น 1 แสดงว่าปิดการใช้งาน Registry Tools เอาไว้
    If RegRead(strKey) = 0 Then
        optRegistryTool(0).Value = True
    Else
        optRegistryTool(1).Value = True
    End If
    
    ' กำหนดค่าที่ใช้ในการทำ Registry Edit เพื่อทดสอบว่ามีการป้องกันการเขียนข้อมูลลงไปที่ USB Flsh Drive หรือไม่
    strKey = "HKLM\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\WriteProtect"
    
    ' ส่งค่า Key ที่เราต้องการทดสอบไป โดยพิจารณาจาก WriteProtect
    ' หากคืนค่ากลับมาเป็น 0 (Enable) แสดงว่าเปิดใช้งาน USB Flash Drive
    ' หากคืนค่ากลับมาเป็น 1 (Disable) แสดงว่าล็อคการใช้งาน USB Flash Drive
    If RegRead(strKey) = 0 Then
        optWriteProtect(0).Value = True
    Else
        optWriteProtect(1).Value = True
    End If
    
End Sub

'---------------------------------------------------------------------------------------------------------
' โปรแกรมย่อยที่รับค่า Key ในการทดสอบเข้ามา และคืนค่ากลับเป็น 0 หากเปิดใช้งาน (Enable)
' คืนค่ากลับเป็น 1 หากปิดการใช้งาน (Disable)
Public Function RegRead(strKey As String) As Byte
' จะคืนค่ากลับเป็น Boolean (True/False) ก็ได้น่ะครับ ... ลองเล่นดู
'---------------------------------------------------------------------------------------------------------
    ' ประกาศตัวแปรแบบ Object
    Dim Obj As Object
    ' เรียกใช้งาน WScript Object
    Set Obj = CreateObject("WScript.Shell")
    
    If Obj.RegRead(strKey) = 0 Then
        RegRead = 0
    Else
        RegRead = 1
    End If
    
    Set Obj = Nothing

End Function

'---------------------------------------------------------------------------------------------------------
' เหตุการณ์ (Events) ที่ต้องการปรับเปลี่ยนค่าใน Registry Edit
Private Sub cmdOK_Click()
'---------------------------------------------------------------------------------------------------------
    Dim Msg As String
    Msg = ""
    
    ' โจทย์ให้ไปคิดแก้ไขเพิ่มเติมเอาเองครับ ... นั่นคือ WriteProtectFlashDrive กับ RegistryTools
    ' เราสามารถลดโค้ดโดยการใช้งานโปรแกรมย่อยร่วมกันตัวเดียวก็ได้ ดูตัวอย่างจากฟังค์ชั่น RegRead
    
    ' เลือก Option (Index = 0) แสดงว่าไม่ได้ล็อคการใช้งาน USB Flash Drive
    If optWriteProtect(0).Value Then
        Call WriteProtectFlashDrive(True)
        Msg = Msg & "คุณอนุญาตให้สามารถเขียนข้อมูลลงใน USB Flash Drive ได้" & vbCrLf
    
    ' เลือก Option (Index = 1) แสดงว่าล็อคการใช้งาน USB Flash Drive
    Else
        Call WriteProtectFlashDrive(False)
        Msg = Msg & "คุณไม่อนุญาตให้สามารถเขียนข้อมูลลงใน USB Flash Drive ได้" & vbCrLf
    End If
    
    ' เลือก Option (Index = 0) แสดงว่าไม่ได้ล็อคการใช้งาน Registry Tools
    If optRegistryTool(0).Value Then
        Call RegistryTools(True)
        Msg = Msg & "คุณอนุญาตให้สามารถใช้งาน Registry Tool ได้"
    
    ' เลือก Option (Index = 1) แสดงว่าล็อคการใช้งาน Registry Tools เอาไว้
    Else
        Call RegistryTools(False)
        Msg = Msg & "คุณไม่อนุญาตให้สามารถใช้งาน Registry Tool ได้"
    End If
    
    ' รายงานผล
    MsgBox Msg, vbOKOnly + vbInformation, "รายงานสถานะ"

End Sub

'---------------------------------------------------------------------------------------------------------
' Tips:
' โปรแกรมย่อย WriteProtectFlashDrive และ RegistryTools
' สามารถลดคำสั่งให้เป็นโปรแกรมย่อยตัวเดียวกัน เพื่อให้ใช้งานร่วมกันได้
'---------------------------------------------------------------------------------------------------------

'---------------------------------------------------------------------------------------------------------
' การรับค่าของฟังค์ชั่นตัวนี้ หากเราไม่ส่งค่าอะไรมาเลย ก็ให้ถือว่า blnEnable เป็นจริง
Public Sub WriteProtectFlashDrive(Optional ByVal blnEnable As Boolean = True)
'---------------------------------------------------------------------------------------------------------
    ' ประกาศตัวแปรแบบ Object
    Dim Obj As Object
    ' เรียกใช้งาน WScript Object
    Set Obj = CreateObject("WScript.Shell")
    
    ' หากเลือก Option  Control ตัวแรก นั่นคือเรากำหนดให้สามารถเขียนข้อมูลลงใน USB Flash Drive ได้
    If blnEnable Then
        Obj.Regwrite "HKLM\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\" & _
                        "WriteProtect", 0, "REG_DWORD"
    Else
        Obj.Regwrite "HKLM\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies\" & _
                        "WriteProtect", 1, "REG_DWORD"
    End If
    
    Set Obj = Nothing

End Sub

'---------------------------------------------------------------------------------------------------------
' การรับค่าของฟังค์ชั่นตัวนี้ หากเราไม่ส่งค่าอะไรมาเลย ก็ให้ถือว่า blnEnable เป็นจริง
Public Sub RegistryTools(Optional ByVal blnEnable As Boolean = True)
'---------------------------------------------------------------------------------------------------------
    ' ประกาศตัวแปรแบบ Object
    Dim Obj As Object
    ' เรียกใช้งาน WScript Object
    Set Obj = CreateObject("WScript.Shell")
    
    ' หากเลือก Option  Control ตัวแรก นั่นคือเรากำหนดให้สามารถใช้งาน Registry Tools ได้
    If blnEnable Then
        Obj.Regwrite "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\" & _
                    "Policies\System\DisableRegistryTools", 0, "REG_DWORD"
    Else
        Obj.Regwrite "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\" & _
                    "Policies\System\DisableRegistryTools", 1, "REG_DWORD"
    End If
    
    Set Obj = Nothing
    
End Sub

'---------------------------------------------------------------------------------------------------------
Private Sub cmdExit_Click()
'---------------------------------------------------------------------------------------------------------
    Set frmWriteProtectUSBFlash = Nothing
    End
End Sub