โค้ดและแนวคิดการแปลงเลขฐาน 10 เป็นฐาน 2 เรื่องหมูๆ ... ไม่บอกก็แทบจะไม่รู้กันเลย

Private Sub Form_Load()
    Text1.Text = Decimal2Binary(9)
End Sub

' ตัวแปร Dec จะเป็นตัวแปรที่รับค่าในการเรียกใช้งานฟังค์ชั่น
' และส่งค่าคืนกลับเป็นแบบ String
Function Decimal2Binary(Dec As Integer) As String
    ' เก็บค่าคำตอบของการหารเอาเศษ (MOD)
    ' อันนี้แล้วไม่จำเป็นต้องใช้ก็ได้ ให้เอาชื่อฟังค์ชั่นตัวมันเองมาเก็บเป็นคำตอบแทนน่ะครับ
    Dim Bit As String
    
    ' DO WHILE ... เงื่อนไขเป็นจริงจะวนรอบ ... เท็จเมื่อไหร่ก็จะออกจากลูป
    Do While (Dec > 0)
        Bit = (Dec Mod 2) & Bit
        Dec = Dec \ 2
    Loop
    
    ' คืนค่ากลับไป (Return)
    Decimal2Binary = Bit
End Function

Do While (Dec >= 0)

การเกิด Error หรืือ ความผิดพลาดจะมีอยู่ 3 แบบ คือ
1. Syntax Error : มาจากการป้อนคำสั่ง ไวยกรณ์ (Syntax) ผิดพลาด Error แบบนี้แก้ไขง่าย เพราะใน VB6 จะชี้ตำแหน่งที่ผิดให้เห็นได้ทันที
2. Run Time Error : ข้อผิดพลาดเกิดขึ้นในระหว่างที่โปรแกรมกำลังทำงานอยู่ เช่น เกิดการกระทำใดๆ (Operator) ที่มีชนิดของข้อมูลไม่ตรงกัน เช่น เอา 1 + "A" เป็นต้น การหาทางแก้ไขความผิดพลาดแบบนี้จะเริ่มยากขึ้น เพราะเราต้องตีความหมายของแต่ละ Error นั้นๆด้วย
   
   
3. Logical Error : ความผิดพลาดนี้เกิดจากการประมวลผลลัพธ์ที่ได้ออกมานั้น ไม่ตรงกับที่เราต้องการ Error แบบนี้จะแก้ไขได้ยากมาก ... การป้องกันที่จะไม่ให้เกิด Error นี้มีเพียงทางเดียว ... ออกแบบโปรแกรมให้รอบคอบ รัดกุมที่สุด และทดสอบให้ดีก่อนที่จะลงมือเขียนคำสั่งเข้าไป

    Do While (Dec > 0)
        ' ลองสลับ Statement ดู
        Dec = Dec \ 2
        Bit = (Dec Mod 2) & Bit
    Loop

    ' เงื่อนไขเป็นเท็จจะทำการวนรอบ หากเป็นจริงจะต้องออกจากลูป
    Do Until (Dec = 0)
        Bit = (Dec Mod 2) & Bit
        Dec = Dec \ 2
    Loop

Private Sub Form_Load()
    ' การแปลงเลขฐาน 10 (ค่า 127) ให้มีขนาดจำนวน 16 บิต
    Text1.Text = Decimal2BinaryFix(127, 16)
End Sub

' Optional หมายถึง หากไม่ส่งค่าใดๆมาฟังค์ชั่น ให้ยึดค่าที่กำหนดไว้ หรือ 8 เป็นค่าเริ่มต้นเสมอ
Function Decimal2BinaryFix(Dec As Integer, Optional NumBit As Byte = 8)
    ' เก็บค่าคำตอบของการหารเอาเศษ (MOD)
    ' อันนี้แล้วไม่จำเป็นต้องใช้ก็ได้ ให้เอาชื่อฟังค์ชั่นตัวมันเองมาเก็บเป็นคำตอบแทนน่ะครับ
    Dim Bit As String
    
    Dim i As Byte   ' นับจำนวนบิต ... BYTE มีค่าเท่ากับ 0 - 255 น่ะครับ ... พี่น้อง
    
    ' ==============================================================
    ' FOR ... NEXT
    ' เนื่องจากลูป For อาศัยการการนับเป็นเงื่อนไข มีค่าเริ่มต้น - สิ้นสุด และ Step ในการนับ
    ' ดังนั้นเราสามารถกำหนดจำนวนบิตที่ต้องการ เพื่อนำมาทำเป็นเงื่อนไขได้โดยตรง
    For i = 1 To NumBit
        Bit = (Dec Mod 2) & Bit
        Dec = Dec \ 2
    Next
    ' คำตอบที่ส่งกลับไปสำหรับคำสั่งวนรอบด้วย FOR ... อาศัยจำนวนบิตเป็นเงื่อนไข (NumBit) แทน
    Decimal2BinaryFix = Bit
End Function