พื้นฐานในการใช้งาน MS FlexGrid ก่อนสร้างความสัมพันธ์แบบ One To Many (ภาค 1)

Option Explicit

' ลบแถว
Private Sub cmdDeleteRow_Click()
    ' หากเหลือเพียง Column Header อยู่เพียง 1 แถว ให้ออกไปจากโปรแกรมย่อยทันที
    If fgData.Rows = 1 Then Exit Sub
    
    ' หากเหลือเพียง 2 แถว ประกอบด้วย Column Header และ ข้อมูล 1 แถว
    If fgData.Rows = 2 And fgData.Row = 1 Then
        ' กำหนดให้ MS FlexGrid เหลือเพียง Column Header โดยอัตโนมัติ
        fgData.Rows = 1
        Exit Sub
    End If
     
    ' หาก MS FlexGrid ไม่ตรงกับเงื่อนไขทางด้านบนสักตัว
    ' ก็ให้ลบแถวปัจจุบันของ MS FlexGrid ออกไปได้เลย โดยใช้ RemoveItem Method
    fgData.RemoveItem fgData.Row

End Sub

' เพิ่มแถว
Private Sub cmdAddRow_Click()
    Dim sRow As Integer
    
    ' เพิ่มจำนวนแถวใน MS FlexGrid อีก 1 แถว
    fgData.Rows = fgData.Rows + 1
    ' ให้แถวปัจจุบันลดลง 1 (เพื่อไม่ให้นับ Column Header)
    sRow = fgData.Rows - 1
    
    ' ใส่ข้อมูลสมมุติเข้าไปตามแถวที่เพิ่มขึ้นมา
    fgData.TextMatrix(sRow, 0) = sRow

End Sub

' ทดสอบตั้งค่าแถวไว้รอก่อน
Private Sub Form_Load()
    Dim i As Integer
    fgData.Rows = 4
    fgData.Cols = 1
    fgData.FixedCols = 0
    fgData.FixedRows = 1
    
    ' ตั้งค่าสมมุติเพื่อทดสอบการแสดงผล
    For i = 1 To 3
        fgData.TextMatrix(i, 0) = i
    Next
End Sub

Option Explicit

' ======================================================
' การเพิ่มแถวใน MS FlexGrid
' ======================================================
Private Sub cmdAddRow_Click()
    Dim CurrentRow As Integer
    
    ' เพิ่มจำนวนแถวใน MS FlexGrid อีก 1 แถว
    fgData.Rows = fgData.Rows + 1
    ' ให้แถวปัจจุบันลดลง 1 (เพื่อไม่ให้นับ Column Header)
    CurrentRow = fgData.Rows - 1
    
    ' แถวใหม่ที่เพิ่มเข้ามา ทำการตั้งค่าข้อมูล (สมมุติ) ให้ดู
    Randomize
    fgData.TextMatrix(CurrentRow, 0) = CurrentRow
    fgData.TextMatrix(CurrentRow, 1) = Chr$(Int(Rnd() * 26) + 65) & Int(100 * Rnd)
    fgData.TextMatrix(CurrentRow, 2) = Format(Int(10000 * Rnd), "0.00")
    ' ใส่จำนวนสินค้าครั้งละ 1 ชิ้น
    fgData.TextMatrix(CurrentRow, 3) = 1
    fgData.TextMatrix(CurrentRow, 4) = Format(fgData.TextMatrix(CurrentRow, 2) * _
                        fgData.TextMatrix(CurrentRow, 3), "0.00")

    ' บังคับให้ Focus ไปที่ MS FlexGrid
    fgData.SetFocus
    SendKeys "{DOWN}"

End Sub

' ======================================================
' การลบแถวรายการออกไป
' ======================================================
Private Sub cmdDeleteRow_Click()
    ' หากเหลือเพียง Column Header อยู่เพียง 1 แถว ให้ออกไปจากโปรแกรมย่อยทันที
    If fgData.Rows = 1 Then Exit Sub
    
    ' หากเหลือเพียง 2 แถว ประกอบด้วย Column Header และ ข้อมูล 1 แถว
    If fgData.Rows = 2 And fgData.Row = 1 Then
        ' กำหนดให้ MS FlexGrid เหลือเพียง Column Header โดยอัตโนมัติ
        fgData.Rows = 1
        Exit Sub
    End If
     
    ' หาก MS FlexGrid ไม่ตรงกับเงื่อนไขทางด้านบนสักตัว
    ' ก็ให้ลบแถวปัจจุบันของ MS FlexGrid ออกไปได้เลย โดยใช้ RemoveItem Method
    fgData.RemoveItem fgData.Row

    ' บังคับให้ Focus ไปที่ MS FlexGrid
    fgData.SetFocus
    SendKeys "{DOWN}"

End Sub

Private Sub Form_Load()
    Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    
    ' ตั้งค่าต่างๆให้กับ MS FlexGrid แบบ Run Time
    Call SetupGrid
    
    ' บังคับให้ Focus ไปที่ MS FlexGrid
    SendKeys "{UP}"

End Sub

' ======================================================
' การตั้งค่าคุณสมบัติของ MS FlexGrid ในลักษณะของ Run Time
' ======================================================
Sub SetupGrid()
    With fgData
        
        .FixedRows = 1
        .FixedCols = 0
        
        ' จำนวนหลักทั้งหมด
        .Cols = 5
        ' ตั้งค่าเริ่มต้นจำนวนแถวทั้งหมดเป็น 1 (เฉพาะ Column Header)
        .Rows = 1
        ' การใช้งานจริงๆ เราใช้หลักแรก (หลัก 0) เพื่อทำการซ่อน Primary Key ไม่ให้ User มองเห็น
        .ColWidth(0) = 0
        .ColWidth(1) = .Width \ 4 - 100
        .ColWidth(2) = .Width \ 4 - 200
        .ColWidth(3) = .Width \ 4 - 100
        .ColWidth(4) = .Width \ 4
        
        .TextMatrix(0, 0) = "PK"
        .TextMatrix(0, 1) = "รหัสสินค้า"
        .TextMatrix(0, 2) = "ราคาสินค้า"
        .TextMatrix(0, 3) = "จำนวน"
        .TextMatrix(0, 4) = "รวมจำนวนเงิน"
    End With
    
    With fgData
        .RowHeightMin = 330
        .SelectionMode = flexSelectionByRow ' Focus แบบเลือกทั้งแถว
        .AllowUserResizing = flexResizeNone ' ไม่อนุญาตให้ปรับขนาดของแถวหรือหลักได้
        .HighLight = flexHighlightWithFocus
        
        ' ปรับตำแหน่งของการแสดงผล
        .FixedAlignment(1) = flexAlignLeftCenter
        .ColAlignment(1) = flexAlignLeftCenter
        .FixedAlignment(2) = flexAlignRightCenter
        .ColAlignment(2) = flexAlignRightCenter
        .FixedAlignment(3) = flexAlignRightCenter
        .ColAlignment(3) = flexAlignRightCenter
        .FixedAlignment(4) = flexAlignRightCenter
        .ColAlignment(4) = flexAlignRightCenter
    
        ' ปรับค่าแสดงผลด้านสี
        .BackColorFixed = RGB(133, 175, 255)
        .ForeColorFixed = vbBlack
        .BackColorBkg = RGB(245, 245, 245)
        .BackColorSel = RGB(121, 255, 53)
        .ForeColorSel = vbBlack
        .BackColor = RGB(255, 255, 204)
        .ForeColor = vbBlack
        .GridColor = vbBlack
    
    End With

End Sub

' ======================================================
' การเกิดเหตุการณ์ค้นหาข้อมูลรหัสสินค้า โดยการกดปุ่ม Enter
' ======================================================
Private Sub txtSearch_KeyPress(KeyAscii As Integer)
    If KeyAscii = vbKeyReturn Then
        Call CheckDataRow
    End If
End Sub

' ======================================================
' การตรวจสอบค่าใน MS FlexGrid ก่อนที่จะแสดงผลรายการใหม่
' ======================================================
Private Sub CheckDataRow()
    Dim CurrentRow As Integer

    ' ตรวจสอบว่าเป็นค่าว่างหรือไม่ หากใช่ก็ออกจากโปรแกรมย่อย (User ไม่มีการคีย์ข้อมูลใดๆ)
    If Trim(txtSearch.Text) = "" Or Len(Trim(txtSearch.Text)) = 0 Then
        txtSearch.SetFocus
        Exit Sub
    End If

    ' =========================================================
    ' เวลานำไปประยุกต์ใช้งานจริง ก็คือ ณ ตรงนี้คือการทำ Query ค้นหาจากฐานข้อมูลก่อน
    ' หากไม่พบข้อมูล (รหัสสินค้าที่ต้องการ) ก็ให้เด้งออกจากโปรแกรมย่อยนี้ไปเลย ...
    ' =========================================================
    
    ' เริ่มต้นการค้นหาข้อมูลในตารางกริด
    For CurrentRow = 1 To fgData.Rows - 1
        ' ค้นหารหัสสินค้าที่อยู่ในหลักที่ 1
        If fgData.TextMatrix(CurrentRow, 1) = Trim(txtSearch.Text) Then
            
            ' หากพบรายการสินค้าเดิมใส่จำนวนสินค้าเพิ่มเข้าไปอีก 1 ทันที ในแถวปัจจุบัน
            fgData.TextMatrix(CurrentRow, 3) = Val(fgData.TextMatrix(CurrentRow, 3)) + 1
            
            ' คูณราคาสินค้า กับจำนวนสินค้าเข้าไปใหม่
            fgData.TextMatrix(CurrentRow, 4) = Format(Val(fgData.TextMatrix(CurrentRow, 3)) * _
                            Val(fgData.TextMatrix(CurrentRow, 2)), "0.00")
                            
            ' เคลียร์ค่า
            txtSearch.Text = ""
            ' จบจากการวนรอบ FOR และ ออกจากโปรแกรมย่อยไปเลยครับ
            Exit Sub
        End If
    Next
    
    ' **************************** นี่คือ LOGIC ที่สำคัญ **************************
   ' เป็นระดับมือใหม่ รายไหนรายนั้น ที่ไม่รู้ว่าเจอ หรือ ไม่เจอ แล้วต้องทำอย่างไรดี
   ' *************************************************************************
    
    ' =================================================
    ' คำตอบก็คือ หากมันวนรอบแถวจนหมด แล้วออกมายังจุดนี้ได้ นั่นก็แสดงว่า
   ' มันยังไม่มีข้อมูลรหัสสินค้าอยู่ในรายการตารางกริดยังไงล่ะครับ ... พี่น้อง
   ' หากเวลาใช้งานจริง ก็คือการนำรายละเอียดของสินค้าเข้าสู่ตารางกริดนั่นเอง
    ' =================================================
    
    ' เพิ่มจำนวนแถวใน MS FlexGrid อีก 1 แถว
    fgData.Rows = fgData.Rows + 1
    
    ' ให้แถวปัจจุบันลดลง 1 (เพื่อไม่ให้นับ Column Header)
    CurrentRow = fgData.Rows - 1
    
    ' แถวใหม่ที่เพิ่มเข้ามา ทำการตั้งค่าข้อมูล (สมมุติ) ให้ดู ยกเว้นรหัสสินค้า
    Randomize
    ' ปกติหลักแรก (หลัก 0) ต้องนำเอาค่า Primary Key ไปซ่อนเอาไว้น่ะครับ ... อย่าลืม
    fgData.TextMatrix(CurrentRow, 0) = CurrentRow
    ' แสดงรหัสสินค้า
    fgData.TextMatrix(CurrentRow, 1) = Trim$(txtSearch.Text)
    ' แสดงราคาสินค้า
    fgData.TextMatrix(CurrentRow, 2) = Format(Int(10000 * Rnd), "0.00")
    ' ใส่จำนวนสินค้าครั้งละ 1
    fgData.TextMatrix(CurrentRow, 3) = 1
    fgData.TextMatrix(CurrentRow, 4) = Format(fgData.TextMatrix(CurrentRow, 2) * _
                                fgData.TextMatrix(CurrentRow, 3), "0.00")
    txtSearch.Text = ""
End Sub