การจัดเก็บข้อมูลตำแหน่ง และ ชื่อไฟล์รูปภาพไว้ในฐานข้อมูล

' ======================================================
' เกิดเหตุการณ์ Double Click หรือ กด Enter ในแต่ละแถวของ MS FlexGrid
' ======================================================
Private Sub fgCustomer_DblClick()
    ' กำหนดหลักที่ทำการอ่าน คือ หลัก 0 ที่เก็บค่า Primary Key ของลูกค้าไว้(CustomerPK) และเราซ่อนเอาไว้ด้วย
    fgCustomer.Col = 0
    ' ดัก Error ไว้ก่อน เผื่อในกรณีที่ไม่มีข้อมูลสักรายการใน MS FlexGrid
    If Val(fgCustomer.Text) <= 0 Or IsNull(fgCustomer.Text) Then Exit Sub
    
    ' =======================================================
    ' ตัวแปร blnNewData และ FormUpdate จะถูกประกาศแบบ Global ไว้ใน gMyDB.bas
    ' =======================================================

    ' บอกว่าเป็นการแก้ไขข้อมูล
    blnNewData = False
    ' ตั้งค่าเริ่มต้นเพื่อแจ้งกลับมาฟอร์มหลักว่าเกิดการเปลี่ยนแปลงข้อมูลหรือไม่ ?
    ' เพื่อให้เกิดการ Refresh แสดงผลใหม่ในตารางกริด
    FormUpdate = False
    frmCustomer.Show vbModal
    
    ' หาก FormUpdate ส่งค่ากลับมาเป็นจริง แสดงว่าเกิดการแก้ไขข้อมูล (Save) ก็ต้องแสดงผลข้อมูลใหม่
    If FormUpdate Then
        Call SetupFgCustomer
        Call DisplayFgCustomer
    End If
End Sub

Option Explicit
' ตัวแปรรับค่า CustomerPK จากฟอร์มหลัก
Dim CusPK As Long

' ประกาศตัวแปรสำหรับรับค่าตำแหน่งไฟล์ภาพ หรือ จะใช้ TextBox ก็ได้ไม่ผิดแต่ประการใด
Dim PicturePath As String


Private Sub Form_Load()
    ' ตั้งหน้าจอ (ฟอร์ม) กึ่งกลาง (เครื่องหมาย \ คือ การหารตัดเศษ ... จะทำงานได้เร็วกว่าการหาร /)
    Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    
    ' เคลียร์หน้าจอแสดงผล
    Call SetupScreen
    
    ' ไม่ให้คีย์ข้อมูลลงไปได้ ... หากต้องการแก้ไข ให้กลับไปดูในบทความที่มีอยู่ด้วยน่ะครับ
    ' จุดประสงค์ของบทความนี้เพื่อต้องการแสดงวิธีการเก็บ Path ของภาพเท่านั้น
    txtCustomerID.Locked = True
    
    ' โหลดรายชื่อจังหวัดเข้ามาสู่ ComboBox
    Call DisplayProvince
    
    ' ส่วนนี้ก็ผ่านไปเลยครับ ให้พิจารณาการแก้ไขข้อมูลอย่างเดียว
    ' If blnNewData Then ... หรือ เขียนง่ายๆแบบนี้ก็ได้
    If blnNewData = True Then
        ' รหัสลูกค้าจะให้ทำงานอัตโนมัติ
        ' เช่น RS("CustomerID") = Right$("CUS0000000" & CountRec, 10)
        txtCustomerID.Text = "[New]"
    ' พิจารณาเฉพาะการแก้ไขข้อมูล
    Else
        ' การรับค่าด้วยตัวแปรจากฟอร์มหลักที่เรียกมา โดยการอ้างอิงไปที่ MS Flex Grid
        CusPK = Val(frmMainCustomer.fgCustomer.Text)
        ' แสดงผลรายการตาม Primary Key ที่ส่งมา
        Call RecordToScreen
    End If
End Sub

'การแสดงผลรายละเอียดของลูกค้า
Sub RecordToScreen()
Set RS = New Recordset
Statement = "SELECT tblCustomer.*, tblProvince.* " & _
                " FROM tblCustomer INNER JOIN tblProvince ON tblCustomer.ProvinceFK = tblProvince.ProvincePK " & _
                " WHERE [CustomerPK] = " & CusPK

    ' การแสดงผลข้อมูล ให้อ่านข้อมูลแบบเดินหน้า (Forward) และ อ่านอย่างเดียว (ReadOnly) จะทำงานได้เร็ว
    RS.Open Statement, ConnDB, adOpenForwardOnly, adLockReadOnly, adCmdText
    
    txtCustomerID.Text = "" & RS("CustomerID")
    txtFirstname.Text = "" & RS("Firstname")
    txtLastname.Text = "" & RS("Lastname")
    txtAddress.Text = "" & RS("Address")
    txtAmphur.Text = "" & RS("Amphur")
    cmbProvince.Text = RS("ProvinceName")
    txtAmphur.Text = "" & RS("Amphur")
    txtPostCode.Text = "" & RS("PostCode")
    
    ' การโหลดตำแหน่งภาพแสดงผลใน image control
    ' ตรวจสอบว่ามีการเก็บตำแหน่งภาพหรือไม่
    ' กรณีนี้ ไม่มีข้อมูล
    If IsNull(RS("CustomerPicture")) Or Trim(RS("CustomerPicture")) = "" Then
        ' ตัวแปรเก็บตำแหน่งไฟล์ภาพจะเป็นค่าว่างเปล่า
        PicturePath = ""
        ' นำภาพอะไรก็ได้ มาแสดงให้ผู้ใช้งานเห็นว่าข้อมูลนี้ไม่มีการจัดเก็บภาพไว้
        Image1.Picture = LoadPicture(App.Path & "\NoPicture.jpg")
        cmdDeletePicture.Enabled = False
        
    ' นำตำแหน่งภาพมาทำการแสดงผล พร้อมกับระบุตำแหน่งให้กับตัวแปร PicturePath ไว้รอก่อนด้วย
    ' แต่ปัญหามันจะเกิดขึ้นในวันข้างหน้า หากหาไฟล์ภาพที่ระบุไม่เจอ ทางแก้ก็คือเขียนโค้ดดัก Error
    Else
        PicturePath = RS("CustomerPicture")
        Image1.Picture = LoadPicture(PicturePath)
        cmdDeletePicture.Enabled = True
    End If
    
    ' ปิดตาราง
    RS.Close:    Set RS = Nothing
End Sub

' Load รายการจังหวัดเข้าสู่ ComboBox
Sub DisplayProvince()
    Set DS = New ADODB.Recordset
    Statement = "SELECT * FROM tblProvince ORDER BY ProvincePK"
    Set DS = ConnDB.Execute(Statement, , adCmdText)
    cmbProvince.Clear
    Do Until DS.EOF
        ' การใส่ "" ไว้ เพื่อป้องกัน Run Time Error 94 ... นั่นคือ ProvinceName อาจเป็นค่าว่าง (Null)
        cmbProvince.AddItem "" & Trim(DS("ProvinceName"))
        DS.MoveNext
    Loop
    DS.Close:    Set DS = Nothing
End Sub

Private Sub cmdBrowse_Click()
On Error Resume Next ' ไม่สน Error ใดๆทั้งสิ้น
    With dlgOpenFile
        .FileName = ""
        .DialogTitle = " เลือกไฟล์ภาพ - Graphics File Format " ' แสดง Title Bar
        .Filter = "ไฟล์ภาพ (*.jpg;*.gif;*.bmp)|*.jpg;*.gif;*.bmp"   ' ประเภทของรูปภาพ
        .CancelError = True ' ยกเลิกทุกๆความผิดพลาด ไม่สนว่างั้นเหอะ ... พี่น้อง
        .ShowOpen ' เปิด Dialog ขึ้นมาเพื่อเลือกไฟล์
    End With
    
    ' การโหลดภาพที่ต้องการจาก Disk เข้ามา
    '  เลือกไฟล์ได้แล้วก็ให้นำไปใส่ไว้ในตัวแปรแบบ Full Path
    PicturePath = dlgOpenFile.FileName
    ' หากไม่มีการเลือกไฟล์ภาพเข้ามา ก็ให้เด้งออกจากโปรแกรมย่อยไปเลย
    If Trim(PicturePath) = "" Or Len(PicturePath) = 0 Then Exit Sub

    ' ให้ image1 แสดงผลภาพ
    Image1.Picture = LoadPicture(PicturePath)
    ' เปิดปุ่มลบภาพไว้ ... เพื่อให้เคลียร์ภาพออกได้
    cmdDeletePicture.Enabled = True

End Sub

' ส่วนของการลบภาพออก
Private Sub cmdDeletePicture_Click()
    ' เมื่อลบภาพออกจาก image1
    ' ให้ Full Path เป็นค่าว่าง
    PicturePath = ""
    ' นำภาพ NoPicture.jpg มาแสดงผลแทน ... แต่ตอนเก็บข้อมูลเราไม่เก็บภาพนี้น่ะครับ เพราะ PicturePath = ""
    Image1.Picture = LoadPicture(App.Path & "\NoPicture.Jpg")
    ' ปิดปุ่มลบภาพ ... เนื่องจากไม่มีภาพมาแสดงผล
    cmdDeletePicture.Enabled = False
End Sub

Sub SaveData()
Dim CountRec As Long

    Set RS = New ADODB.Recordset
    ' ตัวอย่างนี้ผมไม่ได้ทำปุ่มเพิ่มข้อมูลเอาไว้ ... ส่วนนี้ก็ผ่านไปเลยครับ ให้พิจารณาการแก้ไขข้อมูลอย่างเดียว
    If blnNewData Then
        ' หาค่า Primary Key (CustomerPK) ก่อน ... อย่าลืมต้องจัดเรียงด้วย CustomerPK
        Statement = "SELECT * FROM tblCustomer ORDER BY CustomerPK "
        RS.CursorLocation = adUseClient
        RS.Open Statement, ConnDB, adOpenForwardOnly, adLockReadOnly, adCmdText
        ' เงื่อนไขแรกแสดงว่ายังไม่มีข้อมูล
        If RS.BOF Or RS.EOF Then
            CountRec = 1
        Else
            RS.MoveLast
            CountRec = RS("CustomerID") + 1
        End If
        RS.Close
        
        Set RS = New ADODB.Recordset
        Statement = "SELECT tblCustomer.*, tblProvince.* " & _
                            " FROM tblCustomer INNER JOIN tblProvince ON tblCustomer.ProvinceFK = tblProvince.ProvincePK " & _
                            " ORDER BY [CustomerPK] "
        RS.Open Statement, ConnDB, adOpenKeyset, adLockOptimistic, adCmdText
        ' นี่คือการ INSERT น่ะครับ
        RS.AddNew
        RS("CustomerPK") = CountRec
        ' ส่วนนี้ไม่มีอะไรมาก ผมอยากจัดรูปแบบของ CustomerID เช่น CUS0000001
        RS("CustomerID") = "CUS" & Right$("0000000" & CountRec, 7)
    
    ' Edit/แก้ไขข้อมูล
    Else
        Statement = "SELECT tblCustomer.*, tblProvince.* " & _
                            " FROM tblCustomer INNER JOIN tblProvince ON tblCustomer.ProvinceFK = tblProvince.ProvincePK " & _
                            " WHERE [CustomerPK] = " & CusPK
        RS.Open Statement, ConnDB, adOpenKeyset, adLockOptimistic, adCmdText
    
    End If
    
    ' Save Data/บันทึกข้อมูล
    ' ผมว่าผมเขียนโค้ดแบบดั้งเดิมเนี่ย มันอ่านง่าย แก้ไข หาจุดบกพร่องได้ง่ายง่ายกว่า INSERT, UPDATE เป็นไหนๆ
    RS("Firstname") = "" & Trim(txtFirstname.Text)
    RS("Lastname") = "" & Trim(txtLastname.Text)
    RS("Address") = "" & Trim(txtAddress.Text)
    RS("Amphur") = "" & Trim(txtAmphur.Text)
    ' ส่วนนี้ต้องระวังให้ดีน่ะครับ เป็นการนำค่าใน ComboBox ไปตรวจสอบหาค่า Primary Key ของรายชื่อจังหวัด
    ' กรณีของตัวเลข ไม่ต้องมาใส่เครื่องหมาย "" ข้างหน้าน่ะครับ
    RS("ProvinceFK") = CheckProvinceName(cmbProvince.Text)
    '
    RS("PostCode") = "" & Trim(txtPostCode.Text)
    RS("Telephone") = "" & Trim(txtTelephone.Text)
    RS("Facsimile") = "" & Trim(txtFacsimile.Text)
    
    ' เก็บข้อมูลตำแหน่ง และ ชื่อไฟล์ภาพไว้จากค่าตัวแปร
    RS("CustomerPicture") = "" & PicturePath
    
    RS.Update
    
    ' บอกฟอร์มหลักว่าเกิดการเปลี่ยนแปลงข้อมูล
    FormUpdate = True
    MsgBox "บันทึกข้อมูลเรียบร้อย", vbOKOnly + vbInformation, "รายงานสถานะ"
    RS.Close:    Set RS = Nothing
    Set frmCustomer = Nothing
    Unload Me
    
End Sub

' ส่งค่าชื่อตาราง กับ ชื่อของ Combo Box
' การตรวจสอบชื่อจังหวัดจาก ComboBox เพื่อค้นหาค่า ProvincePK แล้วส่งค่าคืนกลับไป
Function CheckProvinceName(ComboText As String) As Integer
        Set DS = New ADODB.Recordset
        ' เปรียบเทียบค่า Text ใน ComboBox ... แต่ต้องการผลที่ได้เป็น ProvincePK เพื่อนำไปบันทึกข้อมูล
        Statement = "SELECT * FROM tblProvince " & "  WHERE [ProvinceName] = " & "'" & ComboText & "'"
        DS.Open Statement, ConnDB, adOpenForwardOnly, adLockReadOnly, adCmdText
        If DS.BOF And DS.EOF Then
            ' หากไม่พบให้ Return ค่ากลับเป็น 0
            ' จากตารางข้อมูลค่า ProvincePK = 0 คือ ไม่ระบุ น่ะครับ ... พี่น้อง
            ' ดังนั้นในตารางข้อมูลคุณต้องกำหนดค่าเป็น 0 ไว้รอไว้ด้วย
            CheckProvinceName = 0
        Else
            ' ส่งค่า ProvincePK กลับไปเก็บลงฐานข้อมูล
            CheckProvinceName = DS("ProvincePK")
        End If
        DS.Close: Set DS = Nothing
End Function